#! /bin/sh

# Copyright (C) 1997 Stephane Levant <sun@tuxfamily.org>

#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2, or (at your option)
#  any later version.

#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.

#  You should have received a copy of the GNU General Public License
#  along with this program; see the file COPYING.  If not, write to the
#  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
#  Boston, MA 02111-1307, USA.

usage() {
cat << EOF >&2
Usage: `basename $0`
  Jeu de master mind
    Le but du jeu est de découvrir un nombre de quatre chiffres (de 1 à 9)
    Il n'y a pas de double ni de blanc.
    A chaque fois, on affiche le nombre de chiffres bons et à la bonne
    place et le nombre de chiffre bon mal placés.
  Les commandes sont :
    q : quitte le programme
    n : commence une nouvelle partie
    h : affiche cette aide
EOF
exit 1 ; }

[ "$1" ] && usage

#stty echoe erase ^h

gawk '

function nouveau_jeu() \
{
  for(i=1;i<=nb;i++)	# On construit le tableau des chiffres à trouver
    {
      x[i]=int(rand()*9+1);
      for(j=1;j<i;j++)		# Tout les chiffres doivent être différents
	if (x[i]==x[j])
	  i--;
    }
  nb_coup=0;		# Nombre de coup joué
  total_bien_place=0;	# Pour le score
  total_mal_place=0;	# Pour le score
}

BEGIN \
{
  print "Master Mind v1 by Sun"
  nb=4;			# Nombre de chiffre à trouver
  srand();		# On initialise rand() avec l heure
  nouveau_jeu();

  while (getline)
    {
      nb_coup++;		# On joue un coup de +

      # Traitement des arguments
      gsub(" ","");		# On enléve les espaces
      if ($0=="q" || $0=="")
	exit 0;
      if ($0=="help" || $0=="h")
	exit 1;
      if ($0=="n")
	{
	  print "Nouveau Jeu..."
	  nouveau_jeu();
	  continue;
	}

      gsub("[^1234567890]","");	# On ne garde que les chiffres
      for (i=1;i<=nb;i++)	# On construit le tableau de chiffre
	t[i]=substr($0,i,1);	# donné en entré

      printf(""); # On se place sur la ligne du dessus et on l efface
      for(i=1;i<=nb;i++)   # On raffiche les chiffres
	printf("%1i",t[i]);

      for(i=1;i<=nb;i++) # On sauvegarde le tableau des chiffres à trouver
	svg[i]=x[i];

      # On regarde les chiffres bien placés
      bien_place=0;
      for(i=1;i<=nb;i++)
	if (x[i]==t[i])
	  {
	    bien_place++;
	    x[i]=-1; # On efface
	  }

      # On regarde les chiffres mal placés
      mal_place=0;
      for(j=1;j<=nb;j++)
	for(i=1;i<=nb;i++)
	  if (x[i]==t[j])
	    {
	      mal_place++;
	      x[i]=-1; # On efface
	    }

      for(i=1;i<=nb;i++) # On restitue le tableau des chiffres à trouver
	x[i]=svg[i];

      print " " bien_place " " mal_place;	# On affiche les statistiques

      if (bien_place==nb)	# On a gagné ?
	{
	  print "Gagné";
	  print "Nb de coup: " nb_coup;
	  print "Score: " 110 - 10 * nb_coup + 3 * total_bien_place \
	    + 1 * total_mal_place;	# score max = 100
	  exit 0;

	}
      total_bien_place+=bien_place;	# Pour le score
      total_mal_place+=mal_place;	# Pour le score
    }
}
'